TUTOS.EU

Lister les services en VbScript

Comment exporter la liste des services d'une série de machine en Vbs

Posez ce vbscript dans un répertoire.
Exécutez le.
Il génèrera dans le même répertoire un fichier csv (à coller dans excel) qui contiendra la liste des services de votre machine.

Option Explicit
'Version du 16/05/2014
'Permet d ecrire dans un fichier la liste des services present sur une liste de machine separee par ;

Dim strComputer
Dim objWMIService, colListOfServices, objService
Dim CheminScriptActuel, CheminFichierResultat, ScriptFileName, Position, objFSO, objFichierResultat
Dim ListeMachines, TableauListeMachines

Const ForReading = 1
Const ForWritting = 2
Const ForAppending = 8


ListeMachines = "." 'Nom de la machine à examiner
'ListeMachines = "NomMachine1;NomMachine2" 'Nom de la machine à examiner


ScriptFileName = wscript.scriptname
Position = InstrRev(ScriptFileName,".")
if (Position > 0) Then ScriptFileName = Left(ScriptFileName, Position - 1)

CheminScriptActuel = Left(wscript.scriptfullname,Len(wscript.scriptfullname)-Len(wscript.scriptname)-1)
CheminFichierResultat = CheminScriptActuel & "\" & ScriptFileName & "_Resultat.txt"

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFichierResultat = objFSO.OpenTextFile(CheminFichierResultat, ForWritting, True)
TableauListeMachines = Split(ListeMachines, ";")

objFichierResultat.WriteLine("strComputer" & VbTab & "Name" & VbTab & "Caption" & VbTab & "DisplayName" & VbTab & "StartMode" & VbTab & "State" & VbTab & "PathName")
For Each strComputer in TableauListeMachines
	Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

	'Set colListOfServices = objWMIService.ExecQuery("Select * from Win32_Service WHERE Name LIKE 'myservicenamelike%'")
	Set colListOfServices = objWMIService.ExecQuery("Select * from Win32_Service")

	For Each objService in colListOfServices
		objFichierResultat.WriteLine(strComputer & VbTab & objService.Name & VbTab & objService.Caption & VbTab & objService.DisplayName & VbTab & objService.StartMode & VbTab & objService.State & VbTab & objService.PathName)
	Next

	Set objWMIService = Nothing
Next

objFichierResultat.Close 'Fermeture du fichier
Set objFichierResultat = Nothing

Set objFSO = Nothing
Wscript.Echo "Termine. Le résultat est dans le répertoire " & CheminScriptActuel
Lien vers le fichier : cliquez ici

Exemple de résultat une fois ouvert dans Excel :


Article(s) précédent(s)